config/packages/patched-derivations.nix

let
  tools = import ./lib/tools.nix;
  patch' = super: tools.patch super "patches/base/${super.pname}";
in with tools;
super: rec {
  kerberized-bind = super.bind.overrideAttrs (attrs: {
    configureFlags = attrs.configureFlags ++ [ "--with-gssapi=${super.krb5.dev}" ];
    buildInputs = attrs.buildInputs ++ [ super.krb5 ];
  });
  kerberized-dnsutils = kerberized-bind.dnsutils;
  kerberized-dig = kerberized-bind.dnsutils;

  ddcci-driver-with-global-control = patch super.linuxPackages.ddcci-driver "patches/kmods/ddcci-driver";

  doas-interactive = patch-rename super.doas "doas-interactive" "patches/base/doas";

  lain-ipfs = patch-rename super.ipfs "lain-ipfs" "patches/base/ipfs";

  glib = patch' super.glib;

  gnome-control-center = super.gnome.gnome-control-center;

  kooha = super.kooha.overrideAttrs (_: {
    postInstall = ''
        substituteInPlace $out/share/applications/io.github.seadve.Kooha.desktop \
          --replace "=Kooha" "=Screen Recorder"
      '';
  });

  nautilus = (patch' super.gnome.nautilus).overrideAttrs (attrs: {
    preFixup = with super;
      let py = (python3.withPackages (ps: with ps; [ ps.pygobject3 ]));
      in attrs.preFixup + ''
        gappsWrapperArgs+=(
          --prefix PYTHONPATH : ${py}/${py.sitePackages}
          )
      '';
  });

  oni2 = super.oni2.overrideAttrs (attrs: {
    nativeBuildInputs = attrs.nativeBuildInputs ++ [
      super.python3
    ];
  });

  terminus_font_fancy = super.terminus_font.overrideAttrs (attrs: {
    patches = (attrs.patches or [ ]) ++ [ "alt/td1.diff" "alt/ll2.diff" ];
  });

  nerdfonts-terminus = super.nerdfonts.override { fonts = [ "Terminus" ]; };

  vte-high-refresh-rate = patch' super.vte;

  tilix-high-refresh-rate = super.tilix.override { gtkd = super.gtkd.override { vte = vte-high-refresh-rate; }; };

  webkitgtk = patch' super.webkitgtk;

  webkitgtk_4_1 = patch' super.webkitgtk_4_1;
}