config/packages/packages.nix

{ inputs, pkgs }:
let
  tools = import ./lib/tools.nix;
  patch' = super: tools.patch super "patches/base/${super.pname}";
  dream2nix = inputs.dream2nix.lib2.init {
    inherit pkgs;
    config = {
      projectRoot = ./dream2nix;
      overridesDirs = [ "${inputs.dream2nix}/overrides" ./dream2nix/overrides ];
    };
  };
  mkNixPak = inputs.nixpak.lib.nixpak {
    inherit (pkgs) lib;
    inherit pkgs;
  };

  sandbox = path: extra: (pkgs.callPackage path ({ inherit mkNixPak; } // extra)).config.env;

  useUpstreamBcachefs = true;
in
{
  amberol = sandbox ./nixpak/amberol { };

  bcachefs-tools = if useUpstreamBcachefs
    then
      pkgs.bcachefs-tools
    else
      pkgs.callPackage ./tools/bcachefs-tools { };

  brig = pkgs.callPackage ./tools/brig { };

  privatevoid-smart-card-ca-bundle = pkgs.callPackage ./data/privatevoid-smart-card-certificate-authority-bundle.nix { };

  jdtls = pkgs.callPackage ./development/langservers/jdtls.nix { };
  
  doom-one-vim = pkgs.callPackage ./vim-plugins/doom-one-vim.nix { };

  fragments-remote = let
    fakeTransmission = pkgs.writeShellScriptBin "transmission-daemon" ''
      exec ${pkgs.coreutils}/bin/sleep +Infinity
    '';

    app = pkgs.fragments.overrideAttrs (_: {
      preFixup = ''
        gappsWrapperArgs+=(
          --prefix PATH : "${pkgs.lib.makeBinPath [ fakeTransmission ] }"
        )
      '';
    });
  in sandbox ./nixpak/fragments { fragments = app; };

  git-remote-ipld = pkgs.callPackage ./tools/git-remote-ipld { };

  hyprspace = pkgs.callPackage ./networking/hyprspace { iproute2mac = null; };

  identity = pkgs.callPackage ./apps/identity { };

  linux-bcachefs = if useUpstreamBcachefs
    then
      pkgs.linuxKernel.kernels.linux_testing_bcachefs
    else
      pkgs.callPackage ./kernels/linux-bcachefs rec {
        kernel = pkgs.linux_6_0;
        inherit (kernel) kernelPatches;
      };

  obfuscate = pkgs.callPackage ./apps/obfuscate { };

  neovim-gtk = pkgs.callPackage ./apps/neovim-gtk { };

  sonnyp-commit = pkgs.callPackage ./apps/sonnyp-commit { };

  steam-metro-skin = import ./data/misc/steam-metro-skin { inherit (pkgs) fetchzip; };

  ungoogled-chromium = sandbox ./nixpak/ungoogled-chromium { };

  vaults = pkgs.callPackage ./apps/vaults { };

  wike = sandbox ./nixpak/wike { };
}