config/modules/autopatch/default.nix

{ pkgs, lib, config, ... }:
{
  nixpkgs.overlays = [
    (self: super:
      (let
        patched = import ../../packages/patched-derivations.nix super;
      in {

        inherit (patched)
          ddcci-driver-with-global-control
          ipfs
          nerdfonts-terminus
          terminus_font_fancy
          webkitgtk
          libfprint
          fprintd
        ;

        doas = patched.doas-interactive;

        hydra-unstable = patched.hydra;

        nix-direnv = super.nix-direnv.override {
          nix = config.nix.package;
        };

      } // lib.optionalAttrs config.services.xserver.desktopManager.gnome.enable {

        ungoogled-chromium = super.ungoogled-chromium.override {
          commandLineArgs = "--enable-features=OverlayScrollbar,OverlayScrollbarFlashAfterAnyScrollUpdate,OverlayScrollbarFlashWhenMouseEnter --auth-server-whitelist=*privatevoid.net";
        };

        gnome = super.gnome.overrideScope' (self': super': {
          inherit (patched) nautilus;
          gnome-control-center = patched.gnome-control-center.override { inherit (self') gnome-user-share; };
          gnome-shell = super'.gnome-shell.overrideAttrs (old: {
            preFixup = old.preFixup + ''
              gappsWrapperArgs+=(
                --prefix XDG_DATA_DIRS : "$XDG_ICON_DIRS"
              )
            '';
          });
        });

        tilix = patched.tilix-high-refresh-rate;


      }))
  ];
}