config/packages/patched-derivations.nix

let
  tools = import ./lib/tools.nix;
  patch' = super: tools.patch super "patches/base/${super.pname}";
in with tools;
super: rec {
  ddcci-driver-with-global-control = patch super.linuxPackages.ddcci-driver "patches/kmods/ddcci-driver";

  doas-interactive = patch-rename super.doas "doas-interactive" "patches/base/doas";

  kubo = patch super.kubo "patches/base/ipfs";

  gnome-control-center = super.gnome.gnome-control-center.overrideAttrs (old: {
    postPatch = (old.postPatch or "") + ''
      echo disabling alert sound chooser
      ${super.xmlstarlet}/bin/xmlstarlet edit -L \
        -s '//property[@name="title" and text()="_Alert Sound"]/..' -t elem -n propertyAlertSoundVisible -v False \
        -s //propertyAlertSoundVisible -t attr -n name -v visible \
        -r //propertyAlertSoundVisible -v property \
        panels/sound/cc-sound-panel.ui

      test "$(${super.xmlstarlet}/bin/xmlstarlet select -t -c '//property[@name="title" and text()="_Alert Sound"]/../property[@name="visible"]/text()' panels/sound/cc-sound-panel.ui)" == "False"
    '';
  });

  libfprint = (patch' super.libfprint).overrideAttrs (old: {
    buildInputs = old.buildInputs ++ [
      super.openssl
    ];
  });

  fprintd = super.fprintd.override { inherit libfprint; };

  nautilus = (patch' super.gnome.nautilus).overrideAttrs (attrs: {
    preFixup = with super;
      let py = (python3.withPackages (ps: with ps; [ ps.pygobject3 ]));
      in attrs.preFixup + ''
        gappsWrapperArgs+=(
          --prefix PYTHONPATH : ${py}/${py.sitePackages}
          )
      '';
  });

  terminus_font_fancy = super.terminus_font.overrideAttrs (attrs: {
    patches = (attrs.patches or [ ]) ++ [ "alt/td1.diff" "alt/ll2.diff" ];
  });

  nerdfonts-terminus = super.nerdfonts.override { fonts = [ "Terminus" ]; };

  vte-high-refresh-rate = patch' super.vte;

  vte-gtk4-high-refresh-rate = patch' super.vte-gtk4;

  tilix-high-refresh-rate = super.tilix.override { gtkd = super.gtkd.override { vte = vte-high-refresh-rate; }; };

  blackbox-high-refresh-rate = (patch' super.blackbox-terminal).override { vte-gtk4 = vte-gtk4-high-refresh-rate; };
}