{ lib, stdenv
, cryfs
, desktop-file-utils
, fetchFromGitHub
, gettext
, glib
, gtk4
, libadwaita
, meson
, ninja
, pkg-config
, python3
, rustPlatform
, wrapGAppsHook
}:

stdenv.mkDerivation rec {
  pname = "vaults";
  version = "0.3.0";

  src = fetchFromGitHub {
    owner = "mpobaschnig";
    repo = "Vaults";
    rev = version;
    sha256 = "sha256-soodx4sNGzDODmh2rxq7D2SrRgyzAVfyGkarX5ANKMg=";
  };

  cargoDeps = rustPlatform.fetchCargoTarball {
    inherit src;
    name = "${pname}-${version}";
    hash = "sha256-dPu8BukAZtDSqRcnA86Vcl27fgrTk8jp7dkR+NQBsWg=";
  };

  nativeBuildInputs = [
    desktop-file-utils
    gettext
    meson
    ninja
    pkg-config
    python3
    rustPlatform.rust.cargo
    rustPlatform.cargoSetupHook
    rustPlatform.rust.rustc
    wrapGAppsHook
  ];

  buildInputs = [
    glib
    gtk4
    libadwaita
  ];

  postPatch = ''
    patchShebangs build-aux/meson_post_install.py
  '';

  preFixup = ''
    gappsWrapperArgs+=(
      --prefix PATH ":" "${lib.makeBinPath [ cryfs ]}"
    );
  '';
}