let
  tools = import ./lib/tools.nix;
  patch' = super: tools.patch super "patches/base/${super.pname}";
in with tools;
super: rec {
  ddcci-driver-with-global-control = patch super.linuxPackages.ddcci-driver "patches/kmods/ddcci-driver";

  doas-interactive = patch-rename super.doas "doas-interactive" "patches/base/doas";

  fragments-remote = let
    fakeTransmission = super.writeShellScriptBin "transmission-daemon" ''
      exec ${super.coreutils}/bin/sleep +Infinity
    '';
  in super.fragments.overrideAttrs (_: {
    preFixup = ''
      gappsWrapperArgs+=(
        --prefix PATH : "${super.lib.makeBinPath [ fakeTransmission ] }"
      )
    '';
  });

  lain-ipfs = patch-rename super.ipfs "lain-ipfs" "patches/base/ipfs";

  gnome-control-center = patch' super.gnome.gnome-control-center;

  nautilus = (patch' super.gnome.nautilus).overrideAttrs (attrs: {
    preFixup = with super;
      let py = (python3.withPackages (ps: with ps; [ ps.pygobject3 ]));
      in attrs.preFixup + ''
        gappsWrapperArgs+=(
          --prefix PYTHONPATH : ${py}/${py.sitePackages}
          )
      '';
  });

  terminus_font_fancy = super.terminus_font.overrideAttrs (attrs: {
    patches = (attrs.patches or [ ]) ++ [ "alt/td1.diff" "alt/ll2.diff" ];
  });

  nerdfonts-terminus = super.nerdfonts.override { fonts = [ "Terminus" ]; };

  vte-high-refresh-rate = patch' super.vte;

  tilix-high-refresh-rate = super.tilix.override { gtkd = super.gtkd.override { vte = vte-high-refresh-rate; }; };

  webkitgtk = patch' super.webkitgtk;

  webkitgtk_4_1 = patch' super.webkitgtk_4_1;
}