{ stdenv
, desktop-file-utils
, fetchFromGitHub
, gettext
, glib
, gtk4
, libadwaita
, meson
, ninja
, openssl
, pkg-config
, python3
, rustPlatform
, wrapGAppsHook
}:

stdenv.mkDerivation rec {
  pname = "tubefeeder";
  version = "1.9.6";

  src = fetchFromGitHub {
    owner = "Tubefeeder";
    repo = "Tubefeeder";
    rev = "v${version}";
    sha256 = "sha256-QB+LGSHwbJWGRx+jsS23B8r6Z43pdh1ECKv2HAb6z8Y=";
  };

  cargoDeps = rustPlatform.fetchCargoTarball {
    inherit src;
    name = "${pname}-${version}";
    hash = "sha256-lSaT7k64MKl6WydLDxgxz4Q4QiX0wxHe6vmJ/c4f/Y0=";
  };

  nativeBuildInputs = [
    desktop-file-utils
    gettext
    meson
    ninja
    pkg-config
    python3
    rustPlatform.rust.cargo
    rustPlatform.cargoSetupHook
    rustPlatform.rust.rustc
    wrapGAppsHook
  ];

  buildInputs = [
    glib
    gtk4
    libadwaita
    openssl
  ];

  postPatch = ''
    patchShebangs build-aux/meson_post_install.py
  '';

  postFixup = ''
    substituteInPlace $out/share/applications/de.schmidhuberj.tubefeeder.desktop \
      --replace /app/bin/tubefeeder tubefeeder
  '';
}