{ pkgs, lib, config, ... }:
{
  nixpkgs.overlays = [
    (self: super:
      (let
        patched = import ../../packages/patched-derivations.nix super;
      in {

        inherit (patched)
          ddcci-driver-with-global-control
          kooha
          nerdfonts-terminus
          oni2
          terminus_font_fancy
          webkitgtk
        ;

        doas = patched.doas-interactive;

        ipfs = patched.lain-ipfs;

        hydra-unstable = patched.hydra;

        nix-direnv = super.nix-direnv.override {
          nix = config.nix.package;
        };

      } // lib.optionalAttrs config.krb5.enable {

        bind = patched.kerberized-bind;
        dnsutils = patched.kerberized-dnsutils;
        dig = patched.kerberized-dig;

      } // lib.optionalAttrs config.services.xserver.desktopManager.gnome.enable {

        ungoogled-chromium = super.ungoogled-chromium.override {
          commandLineArgs = "--enable-features=OverlayScrollbar,OverlayScrollbarFlashAfterAnyScrollUpdate,OverlayScrollbarFlashWhenMouseEnter --auth-server-whitelist=*privatevoid.net";
        };

        gnome = super.gnome.overrideScope' (self': super': {
          inherit (patched) nautilus;
          gnome-control-center = patched.gnome-control-center.override { inherit (self') gnome-user-share; };
        });

        tilix = patched.tilix-high-refresh-rate;

        # backport of https://github.com/NixOS/nixpkgs/pull/162568
        thermald = super.thermald.overrideAttrs (old: {
          configureFlags = assert ! builtins.elem "--disable-werror" old.configureFlags; old.configureFlags ++ [
            "--disable-werror"
          ];
        });


      }))
  ];
}