mirror of
https://github.com/privatevoid-net/nix-super.git
synced 2024-11-27 00:06:16 +02:00
c28de6d96e
For example:
error: `tail' called on an empty list, at
/home/eelco/Dev/nixpkgs/pkgs/applications/misc/hello/ex-2/default.nix:13:7
27 lines
743 B
Nix
27 lines
743 B
Nix
/* This is the implementation of the ‘derivation’ builtin function.
|
||
It's actually a wrapper around the ‘derivationStrict’ primop. */
|
||
|
||
drvAttrs @ { outputs ? [ "out" ], name, builder, system, ... }:
|
||
|
||
let
|
||
|
||
strict = derivationStrict drvAttrs;
|
||
|
||
commonAttrs = drvAttrs // (builtins.listToAttrs outputsList) //
|
||
{ all = map (x: x.value) outputsList;
|
||
inherit drvAttrs;
|
||
};
|
||
|
||
outputToAttrListElement = outputName:
|
||
{ name = outputName;
|
||
value = commonAttrs // {
|
||
outPath = builtins.getAttr outputName strict;
|
||
drvPath = strict.drvPath;
|
||
type = "derivation";
|
||
inherit outputName;
|
||
};
|
||
};
|
||
|
||
outputsList = map outputToAttrListElement outputs;
|
||
|
||
in (builtins.head outputsList).value
|