mirror of
https://github.com/privatevoid-net/nix-super.git
synced 2024-11-24 14:56:15 +02:00
d641e8f717
This was changed in #10611, which caused the derivation paths of anything using builtin:fetchurl to change (i.e. all of Nixpkgs). However, impureEnvVars doesn't actually do anything for builtin:fetchurl, so we can just set it to its historical value.
40 lines
1.1 KiB
Nix
40 lines
1.1 KiB
Nix
{ system ? "" # obsolete
|
|
, url
|
|
, hash ? "" # an SRI hash
|
|
|
|
# Legacy hash specification
|
|
, md5 ? "", sha1 ? "", sha256 ? "", sha512 ? ""
|
|
, outputHash ?
|
|
if hash != "" then hash else if sha512 != "" then sha512 else if sha1 != "" then sha1 else if md5 != "" then md5 else sha256
|
|
, outputHashAlgo ?
|
|
if hash != "" then "" else if sha512 != "" then "sha512" else if sha1 != "" then "sha1" else if md5 != "" then "md5" else "sha256"
|
|
|
|
, executable ? false
|
|
, unpack ? false
|
|
, name ? baseNameOf (toString url)
|
|
, impure ? false
|
|
}:
|
|
|
|
derivation ({
|
|
builder = "builtin:fetchurl";
|
|
|
|
# New-style output content requirements.
|
|
outputHashMode = if unpack || executable then "recursive" else "flat";
|
|
|
|
inherit name url executable unpack;
|
|
|
|
system = "builtin";
|
|
|
|
# No need to double the amount of network traffic
|
|
preferLocalBuild = true;
|
|
|
|
# This attribute does nothing; it's here to avoid changing evaluation results.
|
|
impureEnvVars = [
|
|
"http_proxy" "https_proxy" "ftp_proxy" "all_proxy" "no_proxy"
|
|
];
|
|
|
|
# To make "nix-prefetch-url" work.
|
|
urls = [ url ];
|
|
} // (if impure
|
|
then { __impure = true; }
|
|
else { inherit outputHashAlgo outputHash; }))
|