packages/build-support/fetch-asset: init

packages/build-support/default.nix

@@ -0,0 +1,11 @@
+{ pkgs, ... }:
+
+{
+  imports = [
+    ./options.nix
+  ];
+
+  builders = {
+    fetchAsset = pkgs.callPackage ./fetch-asset { };
+  };
+}

packages/build-support/fetch-asset/default.nix

@@ -0,0 +1,18 @@
+{ fetchurl }:
+
+{ cdnURL ? "https://cdn.privatevoid.net/assets", index }:
+
+let
+  dvc = builtins.fromJSON (builtins.readFile index);
+
+  inherit (builtins.head dvc.outs) sha256 path;
+
+  hashPrefix = builtins.substring 0 2 sha256;
+  hashSuffix = builtins.substring 2 (-1) sha256;
+in
+
+fetchurl {
+  name = path;
+  url = "${cdnURL}/${hashPrefix}/${hashSuffix}";
+  inherit sha256;
+}

packages/build-support/options.nix

@@ -0,0 +1,13 @@
+{ config, lib, ... }:
+
+with lib;
+
+{
+  options.builders = mkOption {
+    description = "Collection of builder functions.";
+    type = with types; attrsOf (functionTo package);
+    default = {};
+  };
+
+  config._module.args = { inherit (config) builders; };
+}

packages/projects.nix

@@ -24,6 +24,7 @@
     imports = [
       ./tests
       ./modules/devshell.nix
+      ./build-support
 
       ./websites/landing/project.nix
     ];